自己寫腳本去更新WINDOWS UPDATE

davidou 2015 年 04 月 10 日

之前我有寫過一篇文章叫做一次下載windows update 更新檔(windows update downloader)

這次我要講的是，直接透過腳本去下載windows update來安裝。

其實以前實驗過，像是直接透過windows update下載安裝更新與我以前那個先把更新下載好在本地更新所花的時間比較過後發現。其實先下載好的還是比較快。

但是其實快沒多少，因為就快了下載的時間。而如果安裝時就有包到像是sp1那種更新的話，其實後續的更新也最多大約1G上下而已下載時間節省的可能約10分鐘左右。(我的下載速度快) 而平常還要維護這個更新包，就會覺得cp值感覺就沒這麼好..

而最近在逛微軟的MSDN有發現，微軟其實有交怎用腳本的方式跑更新。

這對我來說感覺就方便多了。我可以寫一隻程式在灌完系統後，自動安裝所有我想要的軟體後自動更新然後重開在自動更新再重開直到完成為止。

微軟MSDN教學的網址如下 https://msdn.microsoft.com/en-us/library/windows/desktop/aa387102%28v=vs.85%29.aspx

其實就是把下面這些CODE存成黨名叫做WUA_SearchDownloadInstall.vbs

然後再寫一個BAT檔裡面寫的cscript WUA_SearchDownloadInstall.vbs

執行這個BAT檔就可以了。

你如果實際RUN過這個BAT檔你會發現他下載完還是會問你要不要確定更新

按Y開始更新這樣，你可以自行修改下面的腳本。就可以不用按Y 自動跑更新到結束了。

非常的方便。

程式碼Set updateSession = CreateObject("Microsoft.Update.Session")
updateSession.ClientApplicationID = "MSDN Sample Script"
 
Set updateSearcher = updateSession.CreateUpdateSearcher()
 
WScript.Echo "Searching for updates..." & vbCRLF
 
Set searchResult = _
updateSearcher.Search("IsInstalled=0 and Type='Software' and IsHidden=0")
 
WScript.Echo "List of applicable items on the machine:"
 
For I = 0 To searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    WScript.Echo I + 1 & "> " & update.Title
Next
 
If searchResult.Updates.Count = 0 Then
    WScript.Echo "There are no applicable updates."
    WScript.Quit
End If
 
WScript.Echo vbCRLF & "Creating collection of updates to download:"
 
Set updatesToDownload = CreateObject("Microsoft.Update.UpdateColl")
 
For I = 0 to searchResult.Updates.Count-1
    Set update = searchResult.Updates.Item(I)
    addThisUpdate = false
    If update.InstallationBehavior.CanRequestUserInput = true Then
        WScript.Echo I + 1 & "> skipping: " & update.Title & _
        " because it requires user input"
    Else
        If update.EulaAccepted = false Then
            WScript.Echo I + 1 & "> note: " & update.Title & _
            " has a license agreement that must be accepted:"
            WScript.Echo update.EulaText
            WScript.Echo "Do you accept this license agreement? (Y/N)"
            strInput = WScript.StdIn.Readline
            WScript.Echo 
            If (strInput = "Y" or strInput = "y") Then
                update.AcceptEula()
                addThisUpdate = true
            Else
                WScript.Echo I + 1 & "> skipping: " & update.Title & _
                " because the license agreement was declined"
            End If
        Else
            addThisUpdate = true
        End If
    End If
    If addThisUpdate = true Then
        WScript.Echo I + 1 & "> adding: " & update.Title 
        updatesToDownload.Add(update)
    End If
Next
 
If updatesToDownload.Count = 0 Then
    WScript.Echo "All applicable updates were skipped."
    WScript.Quit
End If
     
WScript.Echo vbCRLF & "Downloading updates..."
 
Set downloader = updateSession.CreateUpdateDownloader() 
downloader.Updates = updatesToDownload
downloader.Download()
 
Set updatesToInstall = CreateObject("Microsoft.Update.UpdateColl")
 
rebootMayBeRequired = false
 
WScript.Echo vbCRLF & "Successfully downloaded updates:"
 
For I = 0 To searchResult.Updates.Count-1
    set update = searchResult.Updates.Item(I)
    If update.IsDownloaded = true Then
        WScript.Echo I + 1 & "> " & update.Title 
        updatesToInstall.Add(update) 
        If update.InstallationBehavior.RebootBehavior > 0 Then
            rebootMayBeRequired = true
        End If
    End If
Next
 
If updatesToInstall.Count = 0 Then
    WScript.Echo "No updates were successfully downloaded."
    WScript.Quit
End If
 
If rebootMayBeRequired = true Then
    WScript.Echo vbCRLF & "These updates may require a reboot."
End If
 
WScript.Echo  vbCRLF & "Would you like to install updates now? (Y/N)"
strInput = WScript.StdIn.Readline
WScript.Echo 
 
If (strInput = "Y" or strInput = "y") Then
    WScript.Echo "Installing updates..."
    Set installer = updateSession.CreateUpdateInstaller()
    installer.Updates = updatesToInstall
    Set installationResult = installer.Install()
  
    'Output results of install
    WScript.Echo "Installation Result: " & _
    installationResult.ResultCode 
    WScript.Echo "Reboot Required: " & _ 
    installationResult.RebootRequired & vbCRLF 
    WScript.Echo "Listing of updates installed " & _
    "and individual installation results:" 
  
    For I = 0 to updatesToInstall.Count - 1
        WScript.Echo I + 1 & "> " & _
        updatesToInstall.Item(i).Title & _
        ": " & installationResult.GetUpdateResult(i).ResultCode   
    Next
End If

程式碼
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118	`Set updateSession = CreateObject("Microsoft.Update.Session")` `updateSession.ClientApplicationID = "MSDN Sample Script"` `Set updateSearcher = updateSession.CreateUpdateSearcher()` `WScript.Echo "Searching for updates..." & vbCRLF` `Set searchResult = _` `updateSearcher.Search("IsInstalled=0 and Type='Software' and IsHidden=0")` `WScript.Echo "List of applicable items on the machine:"` `For I = 0 To searchResult.Updates.Count-1` `Set update = searchResult.Updates.Item(I)` `WScript.Echo I + 1 & "> " & update.Title` `Next` `If searchResult.Updates.Count = 0 Then` `WScript.Echo "There are no applicable updates."` `WScript.Quit` `End If` `WScript.Echo vbCRLF & "Creating collection of updates to download:"` `Set updatesToDownload = CreateObject("Microsoft.Update.UpdateColl")` `For I = 0 to searchResult.Updates.Count-1` `Set update = searchResult.Updates.Item(I)` `addThisUpdate = false` `If update.InstallationBehavior.CanRequestUserInput = true Then` `WScript.Echo I + 1 & "> skipping: " & update.Title & _` `" because it requires user input"` `Else` `If update.EulaAccepted = false Then` `WScript.Echo I + 1 & "> note: " & update.Title & _` `" has a license agreement that must be accepted:"` `WScript.Echo update.EulaText` `WScript.Echo "Do you accept this license agreement? (Y/N)"` `strInput = WScript.StdIn.Readline` `WScript.Echo` `If (strInput = "Y" or strInput = "y") Then` `update.AcceptEula()` `addThisUpdate = true` `Else` `WScript.Echo I + 1 & "> skipping: " & update.Title & _` `" because the license agreement was declined"` `End If` `Else` `addThisUpdate = true` `End If` `End If` `If addThisUpdate = true Then` `WScript.Echo I + 1 & "> adding: " & update.Title` `updatesToDownload.Add(update)` `End If` `Next` `If updatesToDownload.Count = 0 Then` `WScript.Echo "All applicable updates were skipped."` `WScript.Quit` `End If` `WScript.Echo vbCRLF & "Downloading updates..."` `Set downloader = updateSession.CreateUpdateDownloader()` `downloader.Updates = updatesToDownload` `downloader.Download()` `Set updatesToInstall = CreateObject("Microsoft.Update.UpdateColl")` `rebootMayBeRequired = false` `WScript.Echo vbCRLF & "Successfully downloaded updates:"` `For I = 0 To searchResult.Updates.Count-1` `set update = searchResult.Updates.Item(I)` `If update.IsDownloaded = true Then` `WScript.Echo I + 1 & "> " & update.Title` `updatesToInstall.Add(update)` `If update.InstallationBehavior.RebootBehavior > 0 Then` `rebootMayBeRequired = true` `End If` `End If` `Next` `If updatesToInstall.Count = 0 Then` `WScript.Echo "No updates were successfully downloaded."` `WScript.Quit` `End If` `If rebootMayBeRequired = true Then` `WScript.Echo vbCRLF & "These updates may require a reboot."` `End If` `WScript.Echo vbCRLF & "Would you like to install updates now? (Y/N)"` `strInput = WScript.StdIn.Readline` `WScript.Echo` `If (strInput = "Y" or strInput = "y") Then` `WScript.Echo "Installing updates..."` `Set installer = updateSession.CreateUpdateInstaller()` `installer.Updates = updatesToInstall` `Set installationResult = installer.Install()` `'Output results of install` `WScript.Echo "Installation Result: " & _` `installationResult.ResultCode` `WScript.Echo "Reboot Required: " & _` `installationResult.RebootRequired & vbCRLF` `WScript.Echo "Listing of updates installed " & _` `"and individual installation results:"` `For I = 0 to updatesToInstall.Count - 1` `WScript.Echo I + 1 & "> " & _` `updatesToInstall.Item(i).Title & _` `": " & installationResult.GetUpdateResult(i).ResultCode` `Next` `End If`

Be the First to comment.

Davidou的 Blog

自己寫腳本去更新WINDOWS UPDATE

Leave a Comment 取消回覆

About Author

DAVIDOU

近期文章

文章分類

最新回應

我的社群網路